#1 2018-07-09 15:26:50

Влад4325
Учасник
Зареєстрований: 2018-07-09
Повідомлень: 8

Помогите новичку

IMG_20180709_150634.jpegНе работает схема
int brightness = 0;
int fadeAmount = 5;
unsigned long currentTime;
unsigned long loopTime ;
void setup(){
    pinMode(10, OUTPUT);
    currentTime  = millis();
    loopTime = currentTime;
}
void loop(){
   if(currentTime >= (loopTime +20)){
        analogWrite(10, brightness);
        brightness = brightness + fadeAmount;
        if(brightness == 0 || brightness == 255){
            fadeAmount = -fadeAmount;
        }
        loopTime = currentTime;
    }
}

Остання редакція Влад4325 (2018-07-09 15:38:07)

Неактивний

#2 2018-07-09 17:12:47

LynX
Учасник
Зареєстрований: 2018-04-19
Повідомлень: 71

Re: Помогите новичку

currentTime не меняется.
При первом проходе цикла условие оказывается ложным, а дальше ничего не меняется, цикл повторяется заново и заново и не выполняется тело.

Замените  if(currentTime >= (loopTime +20)){
на  if(milllis() >= (loopTime +20)){

Неактивний

#3 2018-07-10 14:50:49

Влад4325
Учасник
Зареєстрований: 2018-07-09
Повідомлень: 8

Re: Помогите новичку

Спасибі диод нечел гореть но нет плавного виключення и включення

Остання редакція Влад4325 (2018-07-10 14:51:14)

Неактивний

#4 2018-07-10 15:35:22

LynX
Учасник
Зареєстрований: 2018-04-19
Повідомлень: 71

Re: Помогите новичку

К сожалению яркость светодиода не пропорциональна заполнению ШИМ поданного на него.
Подавайте на него значения от 0 до около 10 (вместо 255). При этом значении светодиод горит почти на полную. Попробуйте разные значения 10, 20, 50....

Неактивний

#5 2018-07-10 16:30:43

renoshnik
Учасник
Зареєстрований: 2017-04-03
Повідомлень: 1,025

Re: Помогите новичку

Нужно сделать логарифмическую таблицу (массив 255 значений)  и по ней рулить СД

Неактивний

#6 2018-07-10 16:37:38

Влад4325
Учасник
Зареєстрований: 2018-07-09
Повідомлень: 8

Re: Помогите новичку

Большое вам спасибо очень помогли

Неактивний

#7 2018-08-26 15:01:07

theoristos
Учасник
Зареєстрований: 2018-08-02
Повідомлень: 26

Re: Помогите новичку

LynX пише:

К сожалению яркость светодиода не пропорциональна заполнению ШИМ поданного на него.

... точнее кривая восприятия глаза далека от линейной. renoshnik верно сказал.

Неактивний

#8 2018-09-16 21:10:46

Йожэг
Учасник
Зареєстрований: 2015-12-30
Повідомлень: 97

Re: Помогите новичку

https://m.youtube.com/watch?v=M9hls9FVa3U

PS: Не подключайте много светодиодов напрямую к Arduino и не пытайтесь одновременно их включить, иначе можете сжечь микроконтроллер.

Остання редакція Йожэг (2018-09-16 22:07:42)

Неактивний

#9 2018-09-16 21:59:22

Йожэг
Учасник
Зареєстрований: 2015-12-30
Повідомлень: 97

Re: Помогите новичку

Поскольку сайт 123d.circuits.io приказал долго жить, выкладываю код сюда. См. подпрограмму transform_brightness:

#define STEP 3 // шаг изменения яркости
#define STEP_DELAY 20 // задержка (мс) при изменении яркости
#define LED_QTY 6 // количество светодиодов, подключённых к выходам с PWM
#define CYCLES_PER_MODE 7 // сколько волн яркости проходит перед сменой режима свечения
#define CYCLE_MODE_QTY 3 // количество режимов свечения
#define MAX_BRIGHT 255 // максимальная яркость свечения

const byte led_pins[LED_QTY] = {3, 5, 6, 9, 10, 11}; // соответствие выводов с ШИМ номерам светодиодов
byte led_brightness[LED_QTY]; // яркость
int brightness_step[LED_QTY]; // шаг изменения яркости
byte cycle_mode = 0;
int cycle_counter = 0;
bool cycle_state = false;

void setup() {
  for (int i = 0; i < LED_QTY; i++) {
    pinMode(led_pins[i], OUTPUT); // переключить все PWM выводы на выход
    brightness_step[i] = STEP;
    led_brightness[i] = (i + 1) * MAX_BRIGHT / LED_QTY;
  }
  pinMode(13, OUTPUT); // встроенный светодиод
}

byte transform_brightness(byte b) {
  long t = (long(b) + 1) * b >> 8; // попытка линеаризовать воспринимаемую яркость
  if (cycle_mode == 1 && t == 0) t = 1;
  return byte(t);
}

void apply_brightness() {
  for (int i = 0; i < LED_QTY; i++) {
    analogWrite(led_pins[i], transform_brightness(led_brightness[i]));   
  }
  if (led_brightness[LED_QTY - 1] > MAX_BRIGHT / 2) {
    if (!cycle_state) {
      cycle_state = true;
      on_cycle_change();
    }
    digitalWrite(13, HIGH); // вкл. встроенный LED
  } else {
    cycle_state = false;
    digitalWrite(13, LOW); // выкл. встроенный LED
  }
}

void got_max_brightness(int &brght, int &stp) {
  switch (cycle_mode) {
    case 0: brght = MAX_BRIGHT; stp = -stp; break;
    case 1: brght = 0; stp = STEP; break;
    case 2: brght = MAX_BRIGHT; stp = -STEP; break;
  }  
}

void got_min_brightness(int &brght, int &stp) {
  switch (cycle_mode) {
    case 0: brght = 0; stp = -stp; break;
    case 1: brght = 0; stp = STEP; break;
    case 2: brght = MAX_BRIGHT; stp = -STEP; break;
  }  
}

void calculate_brightness() {
  int new_brightness;
  for (int i = 0; i < LED_QTY; i++) {
    new_brightness = led_brightness[i] + brightness_step[i];
    if (new_brightness > MAX_BRIGHT) {
      got_max_brightness(new_brightness, brightness_step[i]);
    } else if (new_brightness < 0) {
      got_min_brightness(new_brightness, brightness_step[i]);
    }
    led_brightness[i] = (byte) new_brightness;
  }
}

void on_cycle_change() {
  if (cycle_counter++ > CYCLES_PER_MODE) {
    cycle_counter = 0;
    cycle_mode++;
    if (cycle_mode >= CYCLE_MODE_QTY) {
      cycle_mode = 0;
    }
  }
}

void loop()  {
  apply_brightness();
  calculate_brightness();
  delay(STEP_DELAY);
}

j8m8krL.jpg

Неактивний

Швидке повідомлення

Введіть повідомлення і натисніть Надіслати

Підвал форуму