Форум arduino.ua

   // Підключення усіх бібліотек:
#include <Wire.h>
#include <SPI.h>
#include <SD.h>
#include <HX711.h>

int ADXL345 = 0x53;

float Xa, Ya, Za;  

File dataFile;

const int LOADCELL_DOUT_PIN = 4;
const int LOADCELL_SCK_PIN = 5;

HX711 scale;

void setup() {
  Serial.begin(9600);
  Wire.begin();
  
  Wire.beginTransmission(ADXL345);    // Початок комунікації із сенсором
  Wire.write(0x2D);                   // Звернення до регістру POWER_CTL - 0x2D
  
  Wire.write(8);                      // (8dec -> 0000 1000 binary) біт D3 високий логічний сигнал
  Wire.endTransmission();
  delay(10);

  // Ініціалізація microSD
  if (!SD.begin(10)) {  
    Serial.println("SD card initialization failed!");
    while (1);
  }

  // Створення файлу "log.csv" для запису
  dataFile = SD.open("log.csv", FILE_WRITE);
  if (dataFile) {
    dataFile.println("ADXL345_X,ADXL345_Y,ADXL345_Z,HX711");
    dataFile.close();
  }

  // Ініціалізація HX711 модуля
  scale.begin(LOADCELL_DOUT_PIN, LOADCELL_SCK_PIN);
  scale.set_scale();
}

void loop() {

  // === Зчитування даних модуля ADXL345  === //
  Wire.beginTransmission(ADXL345);
  Wire.write(0x32);                         // Початок з регістру 0x32 (ACCEL_XOUT_H)
  Wire.endTransmission(false);
  Wire.requestFrom(ADXL345, 6, true);       // Загалом зчитування 6-ти регістрів
  Xa = ( Wire.read()| Wire.read() << 8);    // Значення по вісі Х
  Xa = Xa / 256;                            // Для діапазону значень +-2g, потрібно поділити значення на 256
  Ya = ( Wire.read()| Wire.read() << 8);    // Значення по вісі Y
  Ya = Ya / 256;
  Za = ( Wire.read()| Wire.read() << 8);    // Значення по вісі Z
  Za = Za / 256;
  Serial.print("Xa= ");
  Serial.print(Xa);
  Serial.print("   Ya= ");
  Serial.print(Ya);
  Serial.print("   Za= ");
  Serial.println(Za);
  

  // Отримання даних ваги з HX711
  long hx711Value = scale.read_average();
  Serial.print("  HX711: ");
  Serial.println(hx711Value);

  // Відкриття файлу "log.csv" для запису
  dataFile = SD.open("log.csv", FILE_WRITE);
  if (dataFile) {
    // Запис даних з ADXL345 та HX711 у файл
    dataFile.print(Xa);
    dataFile.print(",");
    dataFile.print(Ya);
    dataFile.print(",");
    dataFile.print(Za);
    dataFile.print(",");
    dataFile.println(hx711Value);
    dataFile.close();
  }
  else {
    Serial.println("Error opening log.csv file!");
  }
  // Затримка
  delay(500);
}