Форум arduino.ua

Там же выше Йожэг цититрует rlocman. Берём выдачу и делим на три части: 0B 0049 C7DC. Первая часть означает что-то типа класса карточки -- 0B. А вторую и третью частьи (0049 и C7DC) переводим в десятичную форму, получая "73,51164" -- вот это обычно прямо и пишут на пластиковых карточках. Ваш же считыватель в виндовс "сократил" запятую, добавил ведущий нолик и получилось "07351164".
Всё просто)

Карточка-пропуск с работы в "идеальных" условиях начинает срабатывать с расстояния 6 см. Маленькие брелки-токены (на фото выше) срабатывают, как я уже писал, с 3 см. Жёлтый брелок я брал на местном сайте http://arduino.ua/prod281-RFID_brelok, остальные я не выбирал, мне их дали.

Не 15 см, а 15 мм точно работает. По крайней мере с комплектной антенной. Предел дальности срабатывания моего модуля -- 3 см с копейками. Домофон подъезда срабатывает ещё хуже

Через тонкую медь на стеклотекстолите не работает, через стальную крышку от коробки конфет тоже не хочет от слова совсем. Зато через ДСП столешницы и пластик -- без проблем. Тестовый стенд на фото:

Покажите примеры надписей на карточке и от считывателя.

Это цитата из http://www.rlocman.ru/shem/schematics.html?di=113001

PS: На Arduino даже можно сделать RFID метку с нужным кодом: https://toschprod.wordpress.com/2013/08/05/rfid-spoofer/

Здравствуйте. Собрал схему и загрузил программу, которую опубликовал Йожэгг.  У меня номер написанный на карте не соответствует номеру в мониторе порта. Подскажите: как его можно прочитать?

Подскажите пожалуйста, с помощью такого модуля можно если не скопировать, то эмулировать карточку - т.е. просто "пропищать" в эфир некий ИД? И вообще где можно посмотреть команды которые можно передавать этому модулю? Там же не просто так и TX и RX линии есть?

А как при данного модуля клонировать карту или ключ? Весь интернет перерыл - найти не могу.

Обнаружил, что у меня в домофоне подъезда стоит точно такая же система RFID, как и у продающегося тут модуля RFID RDM6300 125кГц. Взял поиграться, нагуглил примеры, а они или устаревшие, или странные и с ошибками, или сложные.
Надо ж добавить свои 5 копеек!

// Arduino test sketch for http://arduino-ua.com/prod259-125Khz_RFID_modyl_RDM6300
#include <SoftwareSerial.h>
#define STX 2
#define ETX 3

SoftwareSerial softSerial(10, 11); // recommended pins for RX on Mega: 10, 11, 12...
int rx_counter;
byte rx_data[14]; // 1+10+2+1

void setup() {
  rx_counter = 0; // init counter
  Serial.begin(9600);
  softSerial.begin(9600);
}

void loop() {
  if (softSerial.available() > 0) {
    rx_data[rx_counter] = softSerial.read();
    if (rx_counter == 0 && rx_data[0] != STX) {
      Serial.println("Out of sync!"); // do not increment rx_counter
    } else {
      rx_counter++;
    }
    if (rx_counter >= 14) {
      rx_counter = 0; // reset counter
      if (rx_data[0] == STX && rx_data[13] == ETX) { // packet starts with STX and ends with ETX
        byte calc_checksum = 0;
        for (int i = 0; i < 6; i++) { // data with checksum
          calc_checksum ^= ascii_char_to_num(rx_data[i*2+1]) * 16 + ascii_char_to_num(rx_data[i*2+2]);
        }
        if (calc_checksum == 0) {
          Serial.print("ID: ");
          for (int i = 1; i <= 10; i++) {
            Serial.write(rx_data[i]);
          }
          Serial.println();
        } else {
          Serial.println("Checksum ERROR!");
        }
      } else {
          Serial.println("Incorrect packet!");
      }
    } 
  }
}

// convert a single hex character to its byte value using ASCII table (see https://ru.wikipedia.org/wiki/ASCII)
byte ascii_char_to_num(byte a) {
  a -= '0'; // 0..9
  if (a > 9) a -= 7; // A..F
  return a;
}