Форум arduino.ua

sxstalker пише:

заменил digitalWrite(13, LOW); на digitalWrite(13, HIGH);  в самом начале
первый цикл все работает верно

ладно если Вам это сложно, может так будет проще для понимания

unsigned long last_time;

void setup() {
  pinMode(13, OUTPUT);
  digitalWrite(13, LOW); 

}

bool on = false; // поточний стан. з початку - вимкнено;

void loop() {
  unsigned long now = millis();
  static unsigned char task=0;
switch (task)
  {
	case : 0  
	   digitalWrite(13, HIGH); // вмикаєм 
       if (now - last_time >= 2000) { // пройшло 1000 мс ?
       last_time = now;
       on = true; // зберігаєм поточний стан, що увімкнено
       }
       break; 
    case : 1 
          digitalWrite(13, LOW); // вимикаєм       
       if (now - last_time >= 200) { // пройшло 300 мс ?
          last_time = now;
          on = false; // зберігаєм поточний стан, що вимкнено
          }
       break; 
    case : 2    
          digitalWrite(13, HIGH); // вмикаєм	
       if (now - last_time >= 500) { // пройшло 1000 мс ?
          last_time = now;
          on = true; // зберігаєм поточний стан, що увімкнено
        }
       break; 
    case : 3 
           digitalWrite(13, LOW); // вимикаєм	
        if (now - last_time >= 2000) { // пройшло 300 мс ?
           last_time = now;
           on = false; // зберігаєм поточний стан, що вимкнено
        }
       break; 
    default :
       break; 	
  } 


}

Ця конструкція:

sxstalker пише:

  if (!on) {
...
  } else if (on) {
...
  } else if (!on) {
...
  } else if (on) {
...
  } 

не має сенсу. Якщо перша умова "if (!on)" виконалась, то решта вже не виконуються. А якщо не виконалась, то обовʼязково виконається друга - "if (on)", бо вона протилежна першій. А дві останні - ніколи не виконаються.

В попередньому прикладі у вас було всього два стани: світлодіод вимкнено, і світлодіод увімкнено. Тому було достатньо змінної типу bool, у якої всього два можливих значення.

В останньому прикладі у вас чотири стани:
* вимкнено перший раз (на 2000 мс)
* увімкнено перший раз (на 200 мс)
* вимкнено другий раз (на 500 мс)
* увімкнено другий раз (на 2000 мс)

Тому для збереження стану потрібна змінна такого типу, щоб могла приймати як мінімум 4 значення. Для простоти візьмем int. Стани будем нумерувати від 0 до 3. І для ясності перейменуєм змінну з "on" на "state".

int state = 0; // поточний стан. з початку - "0";

void loop() {
  unsigned long now = millis();

  if (state == 0) { // в стані "0"?
    if (now - last_time >= 2000) {
      digitalWrite(13, HIGH);
      last_time = now;
      state = 1; // переходим в стан "1"
    }
  } else if (state == 1) { // в стані "1"?
     if (now - last_time >= 200) {
      digitalWrite(13, LOW);
      last_time = now;
      state = 2; // переходим в стан "2"
    }
  } else if (state == 2) { // в стані "2"?
    if (now - last_time >= 500) {
      digitalWrite(13, HIGH);
      last_time = now;
      state = 3; // переходим в стан "3"
    }
  } else if (state == 3) { // в стані "3" ?
     if (now - last_time >= 2000) {
        digitalWrite(13, LOW);
       last_time = now;
       state = 0; // переходим в початковий стан "0"
    }
  }
}

Абсолютно те ж саме, тільки switch/case замість if/else. Так більш читабельно:

int state = 0; // поточний стан. з початку - "0";

void loop() {
  unsigned long now = millis();

  switch (state)
  {
    case 0:
      if (now - last_time >= 2000) {
        digitalWrite(13, HIGH);
        last_time = now;
        state = 1;
      }
      break;
    case 1:
      if (now - last_time >= 200) {
        digitalWrite(13, LOW);
        last_time = now;
        state = 2;
      }
      break;
    case 2:
      if (now - last_time >= 500) {
        digitalWrite(13, HIGH);
        last_time = now;
        state = 3;
      }
      break;
    case 3:
      if (now - last_time >= 2000) {
        digitalWrite(13, LOW);
        last_time = now;
        state = 0; // переходим в початковий стан "0"
      }
      break;
  }
}

Тепер зверніть увагу на те, що дії при переході між станами практично однакові. Відрізняються тільки
тривалості: 2000, 200, 500, 2000
значення, що передається у digitalWrite: HIGH, LOW, HIGH, LOW
номер наступного стану: 1, 2, 3, 0, 1, 2 ...

Таким чином можна використати один і той же код для циклічного переходу між станами. Тривалості та значення для digitalWrite помістимо у масиви, а значення з масивів вибиратимем по номеру стану:

unsigned int dur[4] = { 2000, 200, 500, 2000 };  // масив тривалостей (duration) для кожного стану
byte led[4] = { HIGH, LOW, HIGH, LOW };          // масив значень digitalWrite для кожного стану
int state = 0; // поточний стан. з початку - "0";

void loop() {
  unsigned long now = millis();

  if (now - last_time >= dur[state]) { // якщо час поточного стану вийшов
    digitalWrite(13, led[state]);      // вмикаєм або вимикаєм світлодіод
    last_time = now;
    state = state + 1; // переходим у наступний стан
    // але максимально можливий номер стану - "3"
    // якщо це був останній - переходим у початковий стан "0"
    if (state > 3) {
      state = 0;
    }
   }
}

Тепер зверніть увагу, що в масиві led всього два варіанти значень для digitalWrite: HIGH і LOW, і вони чергуються. Можна обійтись без цього масиву. Як його позбутись - вам в якості самостійного завдання

как-то так...

unsigned long last_time;

void setup() {
  pinMode(13, OUTPUT);
  digitalWrite(13, LOW); 

}

bool on = false; // поточний стан. з початку - вимкнено;

void loop() {
  unsigned long now = millis();
  static unsigned char task=0;
switch (task)
  {
	  case 0:   
       if (now - last_time >= 2000) { // пройшло 1000 мс ?
          digitalWrite(13, HIGH); // вмикаєм
          last_time = now;
          task=1; // переходим к следующей задаче
        }
       break; 
    case 1:   
       if (now - last_time >= 200) { // пройшло 300 мс ?
          digitalWrite(13, LOW); // вимикаєм
          last_time = now;
          task=2; 
        }
       break; 
    case 2:     
       if (now - last_time >= 500) { // пройшло 1000 мс ?
          digitalWrite(13, HIGH); // вмикаєм
          last_time = now;
          task=3;
        }
       break; 
    case 3: 
        if (now - last_time >= 2000) { // пройшло 300 мс ?
           digitalWrite(13, LOW); // вимикаєм
           last_time = now;
           task=0;
        }
       break; 
    default :
       break; 	
  } 


}

Ця конструкція:

sxstalker пише:

  if (!on) {
...
  } else if (on) {
...
  } else if (!on) {
...
  } else if (on) {
...
  } 

не має сенсу. Якщо перша умова "if (!on)" виконалась, то решта вже не виконуються. А якщо не виконалась, то обовʼязково виконається друга - "if (on)", бо вона протилежна першій. А дві останні - ніколи не виконаються.

В попередньому прикладі у вас було всього два стани: світлодіод вимкнено, і світлодіод увімкнено. Тому було достатньо змінної типу bool, у якої всього два можливих значення.

В останньому прикладі у вас чотири стани:
* вимкнено перший раз (на 2000 мс)
* увімкнено перший раз (на 200 мс)
* вимкнено другий раз (на 500 мс)
* увімкнено другий раз (на 2000 мс)

Тому для збереження стану потрібна змінна такого типу, щоб могла приймати як мінімум 4 значення. Для простоти візьмем int. Стани будем нумерувати від 0 до 3. І для ясності перейменуєм змінну з "on" на "state".

int state = 0; // поточний стан. з початку - "0";

void loop() {
  unsigned long now = millis();

  if (state == 0) { // в стані "0"?
    if (now - last_time >= 2000) {
      digitalWrite(13, HIGH);
      last_time = now;
      state = 1; // переходим в стан "1"
    }
  } else if (state == 1) { // в стані "1"?
     if (now - last_time >= 200) {
      digitalWrite(13, LOW);
      last_time = now;
      state = 2; // переходим в стан "2"
    }
  } else if (state == 2) { // в стані "2"?
    if (now - last_time >= 500) {
      digitalWrite(13, HIGH);
      last_time = now;
      state = 3; // переходим в стан "3"
    }
  } else if (state == 3) { // в стані "3" ?
     if (now - last_time >= 2000) {
        digitalWrite(13, LOW);
       last_time = now;
       state = 0; // переходим в початковий стан "0"
    }
  }
}

Абсолютно те ж саме, тільки switch/case замість if/else. Так більш читабельно:

int state = 0; // поточний стан. з початку - "0";

void loop() {
  unsigned long now = millis();

  switch (state)
  {
    case 0:
      if (now - last_time >= 2000) {
        digitalWrite(13, HIGH);
        last_time = now;
        state = 1;
      }
      break;
    case 1:
      if (now - last_time >= 200) {
        digitalWrite(13, LOW);
        last_time = now;
        state = 2;
      }
      break;
    case 2:
      if (now - last_time >= 500) {
        digitalWrite(13, HIGH);
        last_time = now;
        state = 3;
      }
      break;
    case 3:
      if (now - last_time >= 2000) {
        digitalWrite(13, LOW);
        last_time = now;
        state = 0; // переходим в початковий стан "0"
      }
      break;
  }
}

Тепер зверніть увагу на те, що дії при переході між станами практично однакові. Відрізняються тільки
тривалості: 2000, 200, 500, 2000
значення, що передається у digitalWrite: HIGH, LOW, HIGH, LOW
номер наступного стану: 1, 2, 3, 0, 1, 2 ...

Таким чином можна використати один і той же код для циклічного переходу між станами. Тривалості та значення для digitalWrite помістимо у масиви, а значення з масивів вибиратимем по номеру стану:

unsigned int dur[4] = { 2000, 200, 500, 2000 };  // масив тривалостей (duration) для кожного стану
byte led[4] = { HIGH, LOW, HIGH, LOW };          // масив значень digitalWrite для кожного стану
int state = 0; // поточний стан. з початку - "0";

void loop() {
  unsigned long now = millis();

  if (now - last_time >= dur[state]) { // якщо час поточного стану вийшов
    digitalWrite(13, led[state]);      // вмикаєм або вимикаєм світлодіод
    last_time = now;
    state = state + 1; // переходим у наступний стан
    // але максимально можливий номер стану - "3"
    // якщо це був останній - переходим у початковий стан "0"
    if (state > 3) {
      state = 0;
    }
   }
}

Тепер зверніть увагу, що в масиві led всього два варіанти значень для digitalWrite: HIGH і LOW, і вони чергуються. Можна обійтись без цього масиву. Як його позбутись - вам в якості самостійного завдання

sxstalker пише:

ви мабудь видадили код з цієї сторінки?

Ні

https://wokwi.com/projects/389161053025161217

Якщо мета - розібратись як обробляти натискання кнопки і асинхронно блимати світлодіодом, не заморочуючись на оптимізації споживання, то пропоную такий варіант:

constexpr byte PIN_LED = 11;
constexpr byte PIN_BUTTON = 8;

constexpr byte DEBOUNCE_MS = 20;
constexpr byte DIM_BRIGHTNESS = 64;

constexpr unsigned int DIT_MS = 180;
constexpr unsigned int DAH_MS = DIT_MS * 3;
constexpr unsigned int WORD_SEP_MS = DIT_MS * 7;

const unsigned int sos_pattern[] = {
  DIT_MS, DIT_MS, DIT_MS, DIT_MS, DIT_MS, DIT_MS,
  DAH_MS, DIT_MS, DAH_MS, DIT_MS, DAH_MS, DIT_MS,
  DIT_MS, DIT_MS, DIT_MS, DIT_MS, DIT_MS, WORD_SEP_MS
};

void setup()
{
  pinMode(PIN_BUTTON, INPUT_PULLUP);
  pinMode(PIN_LED, OUTPUT);
}

static inline bool buttonPressed()
{
  return digitalRead(PIN_BUTTON) == LOW; // active low
}

static inline void ledOn(bool on)
{
  digitalWrite(PIN_LED, on); // active high
}

void loop()
{
  static struct {
    bool pressed { false };
    bool debounce { false };
    unsigned long last_press { 0 };
  } button;

  static struct state {
    enum mode {
      OFF = 0,
      ON,
      DIM,
      SOS,
      INVALID
    };
    mode active { mode::OFF };
    bool changed { true };
  } state;

  if (button.debounce) {
    if (millis() - button.last_press >= DEBOUNCE_MS) {
      button.debounce = false;
    }
  }

  bool button_state = buttonPressed();

  if ((button_state != button.pressed) && !button.debounce) {
    button.last_press = millis();
    button.debounce = true;
    button.pressed = button_state;

    if (button_state) {
      state.active = static_cast<state::mode>(state.active + 1);
      if (state.active >= state::mode::INVALID) {
        state.active = state::mode::OFF;
      }

      state.changed = true;
    }
  }

  static struct {
    unsigned long last_change;
    unsigned int pause;
    byte idx;
    bool led;
  } sos;

  if (state.changed) {
    switch (state.active) {
      case state::mode::OFF:
        ledOn(false);
        break;
      case state::mode::ON:
        ledOn(true);
        break;
      case state::mode::DIM:
        analogWrite(PIN_LED, DIM_BRIGHTNESS);
        break;
      case state::mode::SOS:
        sos.led = false;
        ledOn(sos.led);
        sos.idx = 0;
        sos.pause = 100;  // pause before start
        sos.last_change = millis();
        break;
      default: break;
    }
    state.changed = false;
  }

  if (state.active == state::mode::SOS) {
    unsigned long now = millis();
    if (now - sos.last_change >= sos.pause) {
      sos.led = !sos.led;
      ledOn(sos.led);
      sos.pause = sos_pattern[sos.idx++];
      if (sos.idx >= sizeof(sos_pattern) / sizeof(*sos_pattern)) {
        sos.idx = 0;
      }
      sos.last_change = now;
    }
  }
}

Тут кнопка active low, тобто пін підтягнутий до живлення внутрішнім pull-up і замикається кнопкою на землю.
Якщо у вас навпаки, пін 8 підтягнутий зовнішнім резистором до землі і замикається на живлення, замініть вміст buttonPressed() на

return digitalRead(PIN_BUTTON) == HIGH;

і в setup() INPUT_PULLUP замініть на INPUT:

  pinMode(PIN_BUTTON, INPUT);

sxstalker пише:

1. нажимать кнопку нужно специфически немного удерживая чтобы все работало правильно. это ужасно бесит((

У вашій програмі затримки по 150 мс і більше. В цей час процесор не опитує стан кнопки. Для придушення брязкоту контактів у більшості випадків достатньо кількох міллісекунд. А щоб не реагувати на утримання кнопки як на натиснення, потрібно перевіряти зміну стану кнопки з LOW в HIGH.

Для виміру проміжків часу асинхронно бібліотека ардуіно надає функцію millis(). Але нею теж потрібно правильно користуватись, щоб уникнути багів з переповненням.

sxstalker пише:

          analogWrite(ledPin, brightness); // а от тут зовсім не зрозумів чому analog, ну і встановлюэмо яскравість лед на 255

Яскравість регулюється широтно-імпульсною модуляцією. analogWrite() реалізує програмну ШІМ.

sxstalker пише:

  // for (int i = 0; i <= 99999999; i++) { 

Розмір int в AVR gcc - 16 біт, максимальне значення - 32767.

sxstalker пише:

    if (digitalRead(buttonPin) == HIGH) {
      goto bailout;

Для дострокового виходу з циклу достатньо break.

sxstalker пише:

Помогите пожалуйста доработать код правильно. Это мне поможет двигаться далее.

Спочатку реалізуйте просте увімкнення/вимкнення світлодіода по натисненню, щоб воно працювало стабільно. Потім уже додавайте режими, яскравість і т.д.

У вас два логічних потоки: обробка натиснення кнопки і виміри проміжків часу, тому це простіше реалізувати за допомогою скінченного автомата. Ваш switch(mode) / case по суті ним і є, тільки прибрати довгі delay(), а час вимірювати за допомогою millis().

І деякі загальні міркування.
Atmega328 сама по собі в активному режимі на частоті 16 МГц при живленні 5 В споживає близько 10 мА. У вашій програмі процесор постійно активний. У вимкненому стані при ємності джерела живлення в 2500 мА*год воно розрядиться за час порядка 250 годин.

Для мінімізації споживання у вимкненому стані процессор має бути в режимі PowerDown, а натиснення кнопки викликатиме зовнішне переривання. В увімкненому стані потрібно використовувати апаратну ШІМ, а процесор переводити в Idle. Також відключити всю непотрібну периферію, таку як ADC, а тактову частоту знизити. 16 МГц для обробки натиснення кнопки - це перебор.

Також цікаво, як ви збираєтесь реалізувати апаратну частину, особливо в плані живлення. Два Li-Ion аккумулятора? На платі ардуіно лінійний стабілізатор, при живленні 7.5 вольт ККД буде лише 66%. Якщо світлодіод яскравий, його потрібно живити напряму, і бажано через драйвер, щоб напруга живлення не впливала на яскравість.