Форум arduino.ua

/**/
class cl_aaa {
  protected:
    byte pin;
    static const byte sON = 0; // состояние вкл
    static const byte sOFF = 1; // состояние выкл
    unsigned long time1, time, past;
    byte state;
    void set(byte s) {
      past = millis();
      state = s;
      if (state == sON) digitalWrite(pin, HIGH);
      else digitalWrite(pin, LOW);
    }
  public:
    cl_aaa(byte p, unsigned long t1, unsigned long t): pin(p), time1(t1), time(t) {}
    void init() {
      pinMode(pin, OUTPUT);
      set(sON);
    }
    void run() {
      if (state == sON && millis() - past >= time1)set(sOFF);
      if (state == sOFF && millis() - past >= (time - time1))set(sON);
    }
};

cl_aaa aaa1(/*пин*/13,/*время вкл*/(unsigned long )500,/*время цикла*/(unsigned long )1000);
cl_aaa aaa2(/*пин*/12,/*время вкл*/(unsigned long )1000,/*время цикла*/(unsigned long )2000);
//----------------------------------------------------
void setup() {
  aaa1.init();
  aaa2.init();
}
void loop() {
  aaa1.run();
  aaa2.run();
}

//-----замок-----------------------
typedef void(*pDo)();
pDo Do = [] {};
#include <OneWire.h>
OneWire ds(/*пин*/10);
const byte num = 2; // 2 кода
const byte base[num][8] = {
  {0x01, 0x11, 0xF7, 0x43, 0x01, 0x00, 0x00, 0x65},// 1-й код
  {0xEB, 0x00, 0x00, 0x01, 0xB6, 0x7A, 0x12, 0x01} // 2-й код
};
void runLock() {
  byte tmp[8];
  bool ok = false;
  if (ds.search(tmp)) {
    for (int i = 0; i < num; i++) {
      if (base[i][0] == tmp[0] && base[i][1] == tmp[1] &&
          base[i][2] == tmp[2] && base[i][3] == tmp[3] &&
          base[i][4] == tmp[4] && base[i][5] == tmp[5] &&
          base[i][6] == tmp[6] && base[i][7] == tmp[7] ) ok = true;
    }
    for (int i = 7; i > -1; i--) {
      Serial.print(tmp[i], HEX); Serial.print(" ");
    }
    Serial.println();
    if (ok)Do();
    ds.reset_search();
  }
}
//---------автомат-----------------------------
const byte ledPin =/*пин*/13;
// состояния автомата
const byte s0 = 0;// считываем что бы открыть
const byte s1 = 1;// пауза что бы убрать ключ
const byte s2 = 2;// считываем что бы закрыть
const byte s3 = 3;// пауза что бы убрать ключ
pDo run = [] {};
const unsigned long time1s = 1000; // 1 секунда на убрать ключ
unsigned long past;
void set(byte s) {
  past = millis();
  switch (s) {
    case s0:
      digitalWrite(ledPin, LOW);
      Do = [] {set(s1);};
      run = [] {};
      break;
    case s1:
      digitalWrite(ledPin, HIGH);
      Do = [] {};
      run = [] {
        if (millis() - past > time1s)
          set(s2);
      };
      break;
    case s2:
      Do = [] {set(s3);};
      run = [] {};
      break;
    case s3:
      digitalWrite(ledPin, LOW);
      Do = [] {};
      run = [] {
        if (millis() - past > time1s)
          set(s0);
      };
      break;
  }
}
//-------------------------------------------------
void setup() {
  Serial.begin(9600);
  pinMode(ledPin, OUTPUT);
  set(s0);
}

void loop() {
  runLock();
  run();
}

/**/
//#1
const byte ledPin = 13;
enum state1_t {sLedOFF, sLedON} state1;
unsigned long past1;
unsigned long time2s = 2000;
void stand1(state1_t s) {
  state1 = s;
  past1 = millis();
  switch (state1) {
    case sLedOFF:
      digitalWrite(ledPin, LOW);
      break;
    case sLedON:
      digitalWrite(ledPin, HIGH);
      break;
  }
}
//#2
const byte btnPin = 2;
enum state2_t {sBtnOFF, sBtnON} state2;
//---------main()-------------------------
void setup() {
  //#1
  pinMode(ledPin, OUTPUT);
  stand1(sLedOFF);
  //#2
  pinMode(btnPin, INPUT_PULLUP);
  state2 = sBtnOFF;
}
void loop() {
  //#1
  switch (state1) {
    case sLedOFF:
      break;
    case sLedON:
      if (millis() - past1 >= time2s) stand1(sLedOFF);
      break;
  }
  //#2
  bool tmp = digitalRead(btnPin);
  switch (state2) {
    case sBtnOFF:
      if (!tmp) {
        state2 = sBtnON;
        stand1(sLedON);
        delay(50);
      }
      break;
    case sBtnON:
      if (tmp) {
        state2 = sBtnOFF;
        stand1(sLedON);
        delay(50);
      }
      break;
  }
}